Singular

Now (sometime back) I figured out, and it is really easy. You can have as many as you want of these things, while staying in Q. Just add variables d1, d2, d3... in the end of all variables, and add the equations, for example,
d1^2-2,
d2^3-5,
d3^2-7
.......................

Ilia Toli

At present, the syntax of Singular allows only to define algebraic extensions of numbers as Q, and Z_p.

If you want to work over the field [b]Q(a,b)[/b] with say [b] a:=sqrt{2}[/b] and [b]b:=sqrt{3}[/b] then you have to calculate first
a primitive element [b]c[/b](this exists in characteristic 0), such that [b]Q(c) = Q(a,b)[/b] and express [b]a[/b] and [b]b[/b] by [b]c[/b].
In practice a generic lineare combination of the algebraic elements [b]a [/b]and [b]b [/b] is primitive
element [b]c[/b]. The library [b]primitive.lib[/b] [url]http://www.singular.uni-kl.de/Manual/latest/sing_1320.htm#SEC1396[/url] does this task.
(But there are two drawbacks: 1. IMO, the docmention is difficult to understand
2. the (random) delivered minimal polynomials have in general large coefficients which slows down a computation.
The returned minimal polynomial should be further simplified e.g. by using a the LLL-algorithm.)

To your example: The minimal polynomial for a+b is c4-10c2+1=0.
You will find it by squaring a+b, using a2=2, b2=3, and squaring c2-5=2ab again.

With Singular it can be done quickly as follows:
[code]
// find a primitive element
> ring rabc = 0,(a,b,c),dp;
> ideal I = a2-2,b2-3,c-a-b;
> eliminate (I,ab);
_[1]=c4-10c2+1
[/code]
Check that this polynomial is irreducible over the rationals:
[code]
> ring rc =0,c,dp;
> factorize(c4-10c2+1);
[1]:
_[1]=1
_[2]=c4-10c2+1
[2]:
1,1
[/code]
Now find how to express a and b by c (it also shows what -a and -b is; you only need one of them):
[code]
> ring rcab = (0,c),(a,b),dp; minpoly = c4-10c2+1;
> factorize (a2-2);
[1]:
_[1]=1
_[2]=a+(-1/2c3+9/2c)
_[3]=a+(1/2c3-9/2c)
[2]:
1,1,1
> factorize (b2-3);
[1]:
_[1]=1
_[2]=b+(1/2c3-11/2c)
_[3]=b+(-1/2c3+11/2c)
[2]:
1,1,1
[/code]
[b]Remark:[/b] The programm [b]pari/gp[/b] [url]https://pari.math.u-bordeaux.fr/[/url] tells us that also c^4 - 4*c^2 + 1 =0 defines the same number field.

As an alternative approach,
which also addresses to your second question for rings with parameters and algebraic extensions simultaneously,
you can mimic the (double) algebraic extension as follows.

Instead of the parameter [b]a[/b] and [b]minpoly = ...[/b] define the variables [b]a,b[/b] and take
the defining relations [b]a2-2,b2-3 [/b] into your ideal. Then compute a (reduced) Groebner basis.
In this way you can also use additional parameters in the coefficent field:
[code]
> ring rt = (0,t),(x,y,a,b),dp;
> // option(redSB);
> ideal I = ....;
> I = I,a2-2,b2-3;
> ideal I = std(I);
[/code]
To [i]display [/i]the result with [b]a[/b] and [b]b[/b] as parameters switch to another ring:
[code]
> ring rtab = (0,a,b,t),(x,y),dp;
> ideal Istd = imap(rt,Istd);
> Istd;
[/code]

Thank you very much, that worked like a charm. What if I want to involve other things, like Sqrt[3]? Or what if I want to work with square roots and parameters at the same time? The following won't work.

> ring ra = (0, a, L), (x, y), dp;
> minpoly = a^2 - 2;


Best regards.

Work with an algebraic extension of the rationals numbers by definining a minimal polynomial.
[code]
> ring ra = (0,a),(x,y),dp;
> minpoly = a^2-2;
> a^2;
2
> poly f = ax2-1;
> f^2;
2*x4+(-2a)*x2+1
> basering;
// coefficients: QQ[a]/(a2-2)
// number of vars : 2
// block 1 : ordering dp
// : names x y
// block 2 : ordering C
[/code]

I have done this before but forgotten it now. How do you work in a ring of characteristic 0 where the square root of 2 is symbolic rather than a number? Thank you very much. Best regards.