Singular

4.16.3 poly operations

+

addition

-

negation or subtraction

*

multiplication

/, div

division by a polynomial, ignoring the remainder (only implemented for polynomials over QQ, ZZ/p and field extensions of them)
(See also quotient, division, reduce)

%, mod

the remainder from the division by a polynomial (only implemented for polynomials over QQ, ZZ/p and field extensions of them)
(See also quotient, division, reduce)

^, **

power by a positive integer

<, <=, >, >=, ==, <>

comparators (considering leading monomials w.r.t. monomial ordering)

poly_expression [ intvec_expression ]

the sum of monomials at the indicated places w.r.t. the monomial ordering

Example:

  ring R=0,(x,y),dp;
  poly f = x3y2 + 2x2y2 + xy - x + y + 1;
  f;
==> x3y2+2x2y2+xy-x+y+1
  f + x5 + 2;
==> x5+x3y2+2x2y2+xy-x+y+3
  f * x2;
==> x5y2+2x4y2+x3y-x3+x2y+x2
  (x+y)/x;
==> 1
  f/3x2;
==> 1/3xy2+2/3y2
  x5 > f;
==> 1
  x<=y;
==> 0
  x>y;
==> 1
  ring r=0,(x,y),ds;
  poly f = fetch(R,f);
  f;
==> 1-x+y+xy+2x2y2+x3y2
  x5 > f;
==> 0
  f[2..4];
==> -x+y+xy
  size(f);
==> 6
  f[size(f)+1]; f[-1];    // monomials out of range are 0
==> 0
==> 0
  intvec v = 6,1,3;
  f[v];          // the polynom built from the 1st, 3rd and 6th monomial of f
==> 1+y+x3y2