2.2 Standard bases for submodules of free modules

We consider also module orderings <_m on the set of ``monomials'' $\{ x^\alpha e_i \}$ of $K[\underline{x}]^r = \sum_{i=1, \ldots, r} K[\underline{x}] e_i$ which are compatible with the ordering < on $K[\underline{x}]$. That is for all monomials $f, f' \in K[\underline{x}]^r$ and $p, q \in K[\underline{x}]$ we have: f <_m f' implies pf <_m pf' and p < q implies pf <_m qf.

We now fix an ordering <_m on $K[\underline{x}]^r$ compatible with < and denote it also with <. Again we have the notion of coefficient c(f) and leading monomial L(f). < has the important property:

$$\begin{array}{ll} L(qf) = L(q) L(f) & \mbox{for } q \in K[\un... ...), L(g)) & \mbox{for } f, g \in K[\underline{x}]^r. \end{array}$$

Definition 2..4  

1)

${\bf L}(I)$ denotes the submodule of $K[\underline{x}]^r$ generated by $\{L(f) \vert f \in I\}$.

2)

$f_1, \ldots, f_s \in I$ is called a standard basis of I if $\{L(f_1), \ldots, L(f_s)\}$ generates the submodule $L(I) \subset K[\underline{x}]^r$.

In SINGULAR submodules of free modules are defined by a set of generators. These sets are of type module.

SINGULAR example (see [PS]):

// ===========Poincare complex ==========================
// counterexample to a possible generalization of a theorem of Kyoji
// Saito. A complete intersection with exact Poincare complex at 0
// but which is in no coordinate system weighted homogeneous
// see [PS] for an exeact decription.
//
// define (Z/32003)[[x,y,z]]
ring Rp=32003,(x,y,z),(c,ds);
// load additional procedures (milnor, tjurina)
LIB "sing.lib";
// select an example, parametrized by n and m
int n=883; int m=937;
poly f1=xy+z^(n-1);
poly f2=xz+y^(m-1)+yz2;
ideal f=f1,f2;
// define the basering as Rp/f and fetch the data
qring R=std(f);
ideal f=fetch(Rp,f);
poly f1,f2=fetch(Rp,f1),fetch(Rp,f2);
// the module Omega2:
module omega2=
[diff(f1,y),diff(f1,z),0],
[diff(f1,x),0,-diff(f1,z)],
[0,diff(f1,x),diff(f1,y)],
[diff(f2,y),diff(f2,z),0],
[diff(f2,x),0,-diff(f2,z)],
[0,diff(f2,x),diff(f2,y)];
//it can be shown, that the Poincare complex is exact, if (in this case)
//Milnor number(f)+1 = multiplicity(omega2)
omega2=std(omega2);
multiplicity(omega2);
// The Milnor number of the complete intersection f";
milnor(f);
// The Tjurina number of the complete intersection f
tjurina(f);
//since the Milnor number and the Tjurina number do not coincide,
//the singularity is not weighted homogeneous